Cleaning up a bit...

4 files changed, 564 insertions, 0 deletions

diff --git a/src/battle/mechanic/turn_action/btl_turn_actions_attack.erl b/src/battle/mechanic/turn_action/btl_turn_actions_attack.erl
new file mode 100644
index 0000000..52dd3fb
--- /dev/null
+++ b/src/battle/mechanic/turn_action/btl_turn_actions_attack.erl
@@ -0,0 +1,225 @@
+-module(btl_turn_actions_attack).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% TYPES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-export
+(
+   [
+      handle/2
+   ]
+).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% LOCAL FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec handle_attack_sequence
+   (
+      btl_character_current_data:type(),
+      non_neg_integer(),
+      btl_character_current_data:type(),
+      non_neg_integer(),
+      list(btl_attack:step())
+   )
+   -> {list(btl_attack:type()), non_neg_integer(), non_neg_integer()}.
+handle_attack_sequence
+(
+   CharacterCurrentData,
+   CharacterCurrentHealth,
+   TargetCurrentData,
+   TargetCurrentHealth,
+   AttackSequence
+) ->
+   AttackPlannedEffects =
+      lists:map
+      (
+         fun (AttackStep) ->
+            btl_attack:get_description_of
+            (
+               AttackStep,
+               CharacterCurrentData,
+               TargetCurrentData
+            )
+         end,
+         AttackSequence
+      ),
+
+   lists:foldl
+   (
+      fun
+      (
+         AttackEffectCandidate,
+         {AttackValidEffects, AttackerHealth, DefenderHealth}
+      ) ->
+         {AttackResult, NewAttackerHealth, NewDefenderHealth} =
+            btl_attack:apply_to_healths
+            (
+               AttackEffectCandidate,
+               AttackerHealth,
+               DefenderHealth
+            ),
+         case AttackResult of
+            nothing -> {AttackValidEffects, AttackerHealth, DefenderHealth};
+            _ ->
+               {
+                  (AttackValidEffects ++ [AttackResult]),
+                  NewAttackerHealth,
+                  NewDefenderHealth
+               }
+         end
+      end,
+      {
+         [],
+         CharacterCurrentHealth,
+         TargetCurrentHealth
+      },
+      AttackPlannedEffects
+   ).
+
+-spec get_attack_sequence
+   (
+      btl_character:type(),
+      btl_character:type()
+   )
+   -> list(btl_attack:step()).
+get_attack_sequence (Character, TargetCharacter) ->
+   Range =
+      btl_location:dist
+      (
+         btl_character:get_location(Character),
+         btl_character:get_location(TargetCharacter)
+      ),
+
+   {AttackingWeaponID, _} = btl_character:get_weapon_ids(Character),
+   {DefendingWeaponID, _} = btl_character:get_weapon_ids(TargetCharacter),
+
+   AttackingWeapon = shr_weapon:from_id(AttackingWeaponID),
+   DefendingWeapon = shr_weapon:from_id(DefendingWeaponID),
+
+   btl_attack:get_sequence(Range, AttackingWeapon, DefendingWeapon).
+
+
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTED FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec handle
+   (
+      btl_battle_action:type(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+handle (BattleAction, Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Battle = btl_character_turn_data:get_battle(Data),
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterIX = btl_character_turn_data:get_character_ix(Data),
+   CharacterCurrentData =
+      btl_character_turn_data:get_character_current_data(Data),
+
+   Map = btl_battle:get_map(Battle),
+   TargetIX = btl_battle_action:get_target_ix(BattleAction),
+   TargetCharacter = btl_battle:get_character(TargetIX, Battle),
+   TargetCurrentData = btl_character_current_data:new(TargetCharacter, Map),
+
+   true = btl_character:get_is_alive(TargetCharacter),
+
+   AttackSequence = get_attack_sequence(Character, TargetCharacter),
+
+   {AttackEffects, RemainingAttackerHealth, RemainingDefenderHealth} =
+      handle_attack_sequence
+      (
+         CharacterCurrentData,
+         btl_character:get_current_health(Character),
+         TargetCurrentData,
+         btl_character:get_current_health(TargetCharacter),
+         AttackSequence
+      ),
+
+   UpdatedCharacter =
+      btl_character:set_current_health(RemainingAttackerHealth, Character),
+
+   UpdatedBattle =
+      btl_battle:set_character
+      (
+         TargetIX,
+         btl_character:set_current_health
+         (
+            RemainingDefenderHealth,
+            TargetCharacter
+         ),
+         Battle
+      ),
+
+   S0Data = btl_character_turn_data:set_battle(UpdatedBattle, Data),
+   S1Data = btl_character_turn_data:set_character(UpdatedCharacter, S0Data),
+
+   TimelineItem =
+      btl_turn_result:new_character_attacked
+      (
+         CharacterIX,
+         TargetIX,
+         AttackEffects
+      ),
+
+   DBQuery0 =
+      ataxic:update_field
+      (
+         btl_battle:get_characters_field(),
+         ataxic_sugar:update_orddict_element
+         (
+            TargetIX,
+            ataxic:update_field
+            (
+               btl_character:get_current_health_field(),
+               ataxic:constant(RemainingDefenderHealth)
+            )
+         )
+      ),
+
+   DBQuery1 =
+      ataxic:update_field
+      (
+         btl_battle:get_characters_field(),
+         ataxic_sugar:update_orddict_element
+         (
+            CharacterIX,
+            ataxic:update_field
+            (
+               btl_character:get_current_health_field(),
+               ataxic:constant(RemainingAttackerHealth)
+            )
+         )
+      ),
+
+   S0Update =
+      btl_character_turn_update:add_to_timeline
+      (
+         TimelineItem,
+         DBQuery0,
+         Update
+      ),
+
+   S1Update = btl_character_turn_update:add_to_db(DBQuery1, S0Update),
+   S2Update = btl_character_turn_update:set_data(S1Data, S1Update),
+
+   S3Update =
+      btl_victory:handle_character_lost_health
+      (
+         CharacterIX,
+         RemainingAttackerHealth,
+         S2Update
+      ),
+
+   S4Update =
+      btl_victory:handle_character_lost_health
+      (
+         TargetIX,
+         RemainingDefenderHealth,
+         S3Update
+      ),
+
+   S4Update.
diff --git a/src/battle/mechanic/turn_action/btl_turn_actions_move.erl b/src/battle/mechanic/turn_action/btl_turn_actions_move.erl
new file mode 100644
index 0000000..bf023d5
--- /dev/null
+++ b/src/battle/mechanic/turn_action/btl_turn_actions_move.erl
@@ -0,0 +1,186 @@
+-module(btl_turn_actions_move).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% TYPES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-export
+(
+   [
+      handle/2
+   ]
+).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% LOCAL FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec cross
+   (
+      btl_map:type(),
+      list(btl_location:type()),
+      list(btl_direction:enum()),
+      non_neg_integer(),
+      btl_location:type()
+   )
+   -> {btl_location:type(), non_neg_integer()}.
+cross (_Map, _ForbiddenLocations, [], Cost, Location) ->
+   {Location, Cost};
+cross (Map, ForbiddenLocations, [Step|NextSteps], Cost, Location) ->
+   NextLocation = btl_location:apply_direction(Step, Location),
+   NextTileInstance = btl_map:get_tile_instance(NextLocation, Map),
+   NextTileClassID = shr_tile:extract_main_class_id(NextTileInstance),
+   NextTile = shr_tile:from_class_id(NextTileClassID),
+   NextCost = (Cost + shr_tile:get_cost(NextTile)),
+   IsForbidden =
+      lists:foldl
+      (
+         fun (ForbiddenLocation, Prev) ->
+            (Prev or (NextLocation == ForbiddenLocation))
+         end,
+         false,
+         ForbiddenLocations
+      ),
+
+   IsForbidden = false,
+
+   cross(Map, ForbiddenLocations, NextSteps, NextCost, NextLocation).
+
+-spec cross
+   (
+      btl_map:type(),
+      list(btl_location:type()),
+      list(btl_direction:enum()),
+      btl_location:type()
+   )
+   -> {btl_location:type(), non_neg_integer()}.
+cross (Map, ForbiddenLocations, Path, Location) ->
+   cross(Map, ForbiddenLocations, Path, 0, Location).
+
+-spec get_path_cost_and_destination
+   (
+      btl_character_turn_data:type(),
+      list(btl_direction:type())
+   )
+   -> {non_neg_integer(), btl_location:type()}.
+get_path_cost_and_destination (Data, Path) ->
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterIX = btl_character_turn_data:get_character_ix(Data),
+   Battle = btl_character_turn_data:get_battle(Data),
+   Map = btl_battle:get_map(Battle),
+
+   ForbiddenLocations =
+      orddict:fold
+      (
+         fun (IX, Char, Prev) ->
+            IsAlive = btl_character:get_is_alive(Char),
+            if
+               (IX == CharacterIX) -> Prev;
+               (not IsAlive) -> Prev;
+               true ->
+                  ordsets:add_element(btl_character:get_location(Char), Prev)
+            end
+         end,
+         ordsets:new(),
+         btl_battle:get_characters(Battle)
+      ),
+
+   {NewLocation, Cost} =
+      cross
+      (
+         Map,
+         ForbiddenLocations,
+         Path,
+         btl_character:get_location(Character)
+      ),
+
+   {Cost, NewLocation}.
+
+-spec assert_character_can_move
+   (
+      btl_character_turn_data:type(),
+      non_neg_integer()
+   )
+   -> 'ok'.
+assert_character_can_move (Data, Cost) ->
+   CharacterData = btl_character_turn_data:get_character_current_data(Data),
+   CharacterStats= btl_character_current_data:get_statistics(CharacterData),
+   CharacterMovementPoints = shr_statistics:get_movement_points(CharacterStats),
+
+   true = (Cost =< CharacterMovementPoints),
+
+   ok.
+
+-spec commit_move
+   (
+      btl_character_current_data:type(),
+      btl_character_turn_update:type(),
+      list(btl_direction:type()),
+      btl_location:type()
+   )
+   -> btl_character_turn_update:type().
+commit_move (PreviousCurrentData, Update, Path, NewLocation) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterIX = btl_character_turn_data:get_character_ix(Data),
+
+   UpdatedCharacter = btl_character:set_location(NewLocation, Character),
+   S0Data = btl_character_turn_data:set_character(UpdatedCharacter, Data),
+   S1Data = btl_character_turn_data:refresh_character_current_data(S0Data),
+
+   S0Update = btl_character_turn_update:set_data(S1Data, Update),
+   S1Update =
+      btl_turn_actions_stats_change:handle_max_health_changes
+      (
+         PreviousCurrentData,
+         S0Update
+      ),
+
+   TimelineItem =
+      btl_turn_result:new_character_moved(CharacterIX, Path, NewLocation),
+
+   DBQuery =
+      ataxic:update_field
+      (
+         btl_battle:get_characters_field(),
+         ataxic_sugar:update_orddict_element
+         (
+            CharacterIX,
+            ataxic:update_field
+            (
+               btl_character:get_location_field(),
+               ataxic:constant(NewLocation)
+            )
+         )
+      ),
+
+   S2Update =
+      btl_character_turn_update:add_to_timeline
+      (
+         TimelineItem,
+         DBQuery,
+         S1Update
+      ),
+
+   S2Update.
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTED FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec handle
+   (
+      btl_battle_action:type(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+handle (BattleAction, Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   CharacterCurrentData =
+      btl_character_turn_data:get_character_current_data(Data),
+   Path = btl_battle_action:get_path(BattleAction),
+
+   {PathCost, NewLocation} = get_path_cost_and_destination(Data, Path),
+   assert_character_can_move(Data, PathCost),
+
+   commit_move(CharacterCurrentData, Update, Path, NewLocation).
diff --git a/src/battle/mechanic/turn_action/btl_turn_actions_stats_change.erl b/src/battle/mechanic/turn_action/btl_turn_actions_stats_change.erl
new file mode 100644
index 0000000..5fe5444
--- /dev/null
+++ b/src/battle/mechanic/turn_action/btl_turn_actions_stats_change.erl
@@ -0,0 +1,85 @@
+-module(btl_turn_actions_stats_change).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% TYPES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-export
+(
+   [
+      handle_max_health_changes/2
+   ]
+).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% LOCAL FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec mod_current_health
+   (
+      non_neg_integer(),
+      non_neg_integer(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+mod_current_health (CurrentMaxHealth, PreviousMaxHealth, Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterIX = btl_character_turn_data:get_character_ix(Data),
+   PreviousHealth = btl_character:get_current_health(Character),
+
+   PreviousHealthRatio = (PreviousHealth / PreviousMaxHealth),
+   NewHealth =
+      min
+      (
+         CurrentMaxHealth,
+         max(1, round(PreviousHealthRatio * CurrentMaxHealth))
+      ),
+
+   UpdatedCharacter = btl_character:set_current_health(NewHealth, Character),
+   UpdatedData = btl_character_turn_data:set_character(UpdatedCharacter, Data),
+   S0Update = btl_character_turn_update:set_data(UpdatedData, Update),
+
+   DBQuery =
+      ataxic:update_field
+      (
+         btl_battle:get_characters_field(),
+         ataxic_sugar:update_orddict_element
+         (
+            CharacterIX,
+            ataxic:update_field
+            (
+               btl_character:get_current_health_field(),
+               ataxic:constant(NewHealth)
+            )
+         )
+      ),
+
+   S1Update =  btl_character_turn_update:add_to_db(DBQuery, S0Update),
+
+   S1Update.
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTED FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec handle_max_health_changes
+   (
+      btl_character_current_data:type(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+handle_max_health_changes (PreviousData, Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   CurrentData = btl_character_turn_data:get_character_current_data(Data),
+   CurrentStats =  btl_character_current_data:get_statistics(CurrentData),
+   PreviousStats = btl_character_current_data:get_statistics(PreviousData),
+
+   CurrentMaxHealth = shr_statistics:get_health(CurrentStats),
+   PreviousMaxHealth = shr_statistics:get_health(PreviousStats),
+
+   case (CurrentMaxHealth == PreviousMaxHealth) of
+      true -> Update;
+      _ -> mod_current_health(CurrentMaxHealth, PreviousMaxHealth, Update)
+   end.
diff --git a/src/battle/mechanic/turn_action/btl_turn_actions_switch_weapon.erl b/src/battle/mechanic/turn_action/btl_turn_actions_switch_weapon.erl
new file mode 100644
index 0000000..119dbe7
--- /dev/null
+++ b/src/battle/mechanic/turn_action/btl_turn_actions_switch_weapon.erl
@@ -0,0 +1,68 @@
+-module(btl_turn_actions_switch_weapon).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% TYPES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-export
+(
+   [
+      handle/1
+   ]
+).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% LOCAL FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTED FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec handle
+   (
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+handle (Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterCurrentData =
+      btl_character_turn_data:get_character_current_data(Data),
+   CharacterIX = btl_character_turn_data:get_character_ix(Data),
+
+   {PrimaryWeaponID, SecondaryWeaponID} = btl_character:get_weapon_ids(Character),
+
+   UpdatedWeaponIDs = {SecondaryWeaponID, PrimaryWeaponID},
+   UpdatedCharacter = btl_character:set_weapon_ids(UpdatedWeaponIDs, Character),
+
+   S0Data = btl_character_turn_data:set_character(UpdatedCharacter, Data),
+   S1Data = btl_character_turn_data:refresh_character_current_data(S0Data),
+
+   S0Update = btl_character_turn_update:set_data(S1Data, Update),
+   S1Update =
+      btl_turn_actions_stats_change:handle_max_health_changes
+      (
+         CharacterCurrentData,
+         S0Update
+      ),
+
+   TimelineItem = btl_turn_result:new_character_switched_weapons(CharacterIX),
+
+   DBQuery =
+      ataxic:update_field
+      (
+         btl_battle:get_characters_field(),
+         ataxic_sugar:update_orddict_element
+         (
+            CharacterIX,
+            ataxic:update_field
+            (
+               btl_character:get_weapons_field(),
+               ataxic:constant(UpdatedWeaponIDs)
+            )
+         )
+      ),
+
+   btl_character_turn_update:add_to_timeline(TimelineItem, DBQuery, S1Update).